10 KEY OFF: CLS: PRINT"Welcome to home page, a simple webpage generator."
20 PRINT: PRINT"Enter the filename for this page. If it's the main page then it should be"
30 PRINT"named 'index.htm.' Subsequent pages can be named anything else."
40 LINE INPUT "ENTER FILENAME: ";FILENAME$
50 PRINT: PRINT"Enter the title you are going to use for this page. It will appear at"
60 PRINT"the top of each page and identifies the page. Example:"
70 PRINT"                                            My Home Page              "
80 ?"Enter title": line input TITLE$
90 CLS
100 OPEN "a",1,FILENAME$
110 PRINT#1,"<html>"
120 PRINT#1,"<head>"
130 PRINT#1,"<title>"+TITLE$+"</TITLE>"
140 PRINT#1,"</head>"
150 PRINT#1,"<body>"
160 REM body goes here
170 REM text entry
180 PRINT"Begin entering text below this line. Press enter on a blank line for the options menu."
190 LINE INPUT BODY$: IF BODY$ = "" GOTO 210 ELSE GOTO 200
200 PRINT#1,BODY$: GOTO 190
210 REM options menu
220 PRINT"<c>enter text  <l>ink reference  <m>ail tag  <p>aragraph"
230 PRINT"<q>uit  <r>eturn to text entry": K$ = INPUT$(1)
240 IF K$ = "c" GOTO 380
250 IF K$ = "l" GOTO 320
260 IF K$ = "m" GOTO 450
270 IF K$ = "p" GOTO 430
280 IF K$ = "q" GOTO 300
290 IF K$ = "r" GOTO 170 ELSE GOTO 210
300 PRINT#1,"</body>
310 PRINT#1,"</html>": GOTO 500
320 REM link reference
330 PRINT"Enter link reference here, usually to another page or place on the web or to a"
340 ?"picture or sound file(example: page2.htm)"
345 line input link$
350 ?"Enter link description here (example: Click here for XXX)"
355 line input DESCRIPTION$
360 HREF$ = "<p><A HREF="+CHR$(34)+LINK$+CHR$(34)+">"+DESCRIPTION$+"</A>"
370 PRINT#1,HREF$: GOTO 180
380 REM center text
390 PRINT"Enter line to be centered below"
400 LINE INPUT CENTERTEXT$
410 CENTERED$ = "<p><center>"+CENTERTEXT$+"<center>"
420 PRINT#1,CENTERED$: GOTO 180
430 REM paragraph
440 PRINT#1,"<p><p>": GOTO 170
450 REM mail tag
460 LINE INPUT "Enter e-mail address to be used: ";MAILADR$
470 LINE INPUT "Enter mail message (example: Click here to e-mail me.): ";MAILMSG$
480 MAILTAG$ = "<p><A HREF="+CHR$(34)+"mailto:"+MAILADR$+CHR$(34)+">"+MAILMSG$+"</a><P>"
490 PRINT#1,MAILTAG$: GOTO 180
500 PRINT"Closing "FILENAME$:CLOSE: SYSTEM
